blob: 7fe10d069ed78fb7e0d4db3ab9a4aed361e3fc2a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Maintainer: Felix Barz <skycoder42.de@gmx.de>
pkgbase=qt5-jsonserializer
pkgname=(qt5-jsonserializer qt5-jsonserializer-doc)
group=qt5-jsonserializer-full
pkgver=3.3.0
pkgrel=2
pkgdesc="A library to perform generic seralization and deserialization of QObjects"
arch=('i686' 'x86_64')
url="https://github.com/Skycoder42/QtJsonSerializer"
license=('BSD')
depends=('qt5-base')
makedepends=('git' 'qt5-tools' 'python' 'doxygen' 'graphviz')
optdepends=("repkg: Automatically rebuild the package on dependency updates")
_pkgfqn=$pkgname-$pkgver
source=("$_pkgfqn::git+https://github.com/Skycoder42/QtJsonSerializer.git#tag=$pkgver"
"$pkgname.rule")
sha256sums=('SKIP'
'1b52eef5216017cfb4b399df1775950db544550a68a542053efe00eb8ef34911')
prepare() {
mkdir -p build
}
build() {
cd build
qmake "../$_pkgfqn/"
make
make doxygen
}
check() {
cd build
make run-tests
}
package_qt5-jsonserializer() {
cd build
cd src/jsonserializer
make INSTALL_ROOT="$pkgdir" install
cd ../..
# Drop QMAKE_PRL_BUILD_DIR because reference the build dir
find "$pkgdir/usr/lib" -type f -name '*.prl' \
-exec sed -i -e '/^QMAKE_PRL_BUILD_DIR/d' {} \;
install -D -m644 "../$_pkgfqn/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -D -m644 "../${pkgname}.rule" "$pkgdir/etc/repkg/rules/system/${pkgname}.rule"
}
package_qt5-jsonserializer-doc() {
depends=('qt5-jsonserializer')
optdepends=()
cd build/doc
make INSTALL_ROOT="$pkgdir" install
# DROP file paths from doc tags
find "$pkgdir/usr/share/doc/qt" -type f -name '*.tags' \
-exec sed -i -e 's:<path>[^<]*<\/path>:<path>/usr/include/qt/QtJsonSerializer</path>:g' {} \;
# install manpages
install -Dm644 -t "$pkgdir/usr/share/man/man3" man/man3/*.3
}
|