PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Dāvis Mosāns <davispuh at gmail dot com>

_pkgname=qt5-script
pkgname=$_pkgname-git
pkgver=v5.6.0.alpha1.r3.g0967458
pkgrel=1
pkgdesc='Classes for making Qt applications scriptable. Provided for Qt 4.x compatibility'
arch=('i686' 'x86_64')
url='https://code.qt.io/cgit/qt/qtscript.git'
license=('GPL3' 'LGPL')
depends=("qt5-base")
makedepends=('git')
provides=("$_pkgname")
conflicts=("$_pkgname")
source=("$_pkgname::git+https://code.qt.io/qt/qtscript.git#branch=dev")
sha256sums=('SKIP')

pkgver() {
    cd "$srcdir/$_pkgname"
    git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
    cd "$srcdir"
    mkdir -p build
}

build() {
    cd "$srcdir/build"

    qmake "$srcdir/$_pkgname"
    make
}

package() {
    cd "$srcdir/build"

    make INSTALL_ROOT="$pkgdir" install

    install -D -m644 $srcdir/$_pkgname/LGPL_EXCEPTION.txt "${pkgdir}"/usr/share/licenses/"${pkgname}"/LGPL_EXCEPTION.txt
}