blob: e7df0ee6f3e95c07f13e5f12284da0e7de542d13 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Gimmeapill <gimmeapill at gmail dot com>
# Contributor: David Runge <dave@sleepmap.de>
# Contributor: Ray Rashif <schiv@archlinux.org>
# Contributor: speps <speps at aur dot archlinux dot org>
# Contributor: Philipp Überbacher <hollunder at gmx dot at>
pkgname=qtractor-git
pkgver=0.9.19.r0.g5de89828
pkgrel=1
pkgdesc="Audio/MIDI multitrack sequencer"
arch=('i686' 'x86_64')
url="http://qtractor.sourceforge.net/"
license=('GPL')
groups=('pro-audio')
depends=('alsa-lib' 'aubio' 'hicolor-icon-theme' 'jack' 'liblo' 'libmad' 'lilv' 'libvorbis' 'qt5-base' 'rubberband' 'suil')
makedepends=('dssi' 'git' 'ladspa' 'libogg' 'libsamplerate' 'libsndfile' 'lv2' 'qt5-tools')
optdepends=('dssi-vst: win32 VST support')
provides=('qtractor')
conflicts=('qtractor')
source=("${pkgname%-*}::git+https://github.com/rncbc/qtractor.git")
md5sums=('SKIP')
pkgver() {
cd "${srcdir}/${pkgname%-*}"
# cutting off the "qtractor_" prefix present in the git tag + remaining underscores (ugly but gets the job done).
git describe --long | sed 's/^qtractor_//;s/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/\_/./g'
}
build() {
cd "${srcdir}/${pkgname%-*}"
make -f Makefile.git
./configure --prefix=/usr \
--libdir=/usr/lib
make
}
package() {
cd "${srcdir}/${pkgname%-*}"
make DESTDIR="${pkgdir}" install
# docs
install -t "${pkgdir}/usr/share/doc/${pkgname}" \
-vDm 644 {AUTHORS,README,README.VST,TODO}
}
|