PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

# Contributor: Slash <demodevil5 [at] yahoo [dot] com>

pkgname=quake4
pkgver=1.4.2
pkgrel=2
pkgdesc="Quake 4 Engine. You need the retail .pk4 files to play."
url="http://www.quake4game.com/"
license=('custom:"Quake 4"' \
         'custom:"PunkBuster"')
depends=('gcc-libs' 'libgl' 'sdl' 'zlib')
arch=('i686')
install=quake4.install
source=('quake4.desktop' 'quake4.launcher' 'quake4-dedicated.launcher' 'quake4-smp.launcher' \
"http://www.1337-server.net/quake4/quake4-linux-${pkgver}.x86.run.gz")
md5sums=('c05b4551aa7cc8728eee9e3f94fcea1e'
         'ece76fd2e52d2eec7584ab1e8832410b'
         'b479a067fdf376384e39cbff41911327'
         '19acb4c06f9c8e7bf03aa021c56e4242'
         'b186954ab5fbadd57f7ca9519b5b0503')

build() {
    cd $srcdir

    # Create Destination Directories
    install -d $pkgdir/opt/

    # Make Installer Executable
    chmod +x $srcdir/quake4-linux-${pkgver}.x86.run

    # Extract Files from Installer
    $srcdir/quake4-linux-${pkgver}.x86.run --noexec --target quake4

    # Move pk4 files to correct location
    mv $srcdir/quake4/us/q4base/*.pk4 \
        $srcdir/quake4/q4base/

    # Move Executables and Libraries
    install -m 755 -t $srcdir/quake4/ \
        $srcdir/quake4/bin/Linux/x86/{lib*,q4ded*,quake4*}

    # Make Everything World-Readable
    chmod -R a+r $srcdir/quake4/

    # Remove Unneeded Files
    rm -rf $srcdir/quake4/{germany/,setup.data/,setup.sh,us/,bin/}

    # Move Quake4 to Destination Directory
    mv $srcdir/quake4 $pkgdir/opt/

    # Install Launcher (Client)
    install -D -m 755 $srcdir/quake4.launcher \
        $pkgdir/usr/bin/quake4

    # Install Launcher (Client - SMP)
    install -D -m 755 $srcdir/quake4-smp.launcher \
        $pkgdir/usr/bin/quake4-smp

    # Install Launcher (Server)
    install -D -m 755 $srcdir/quake4-dedicated.launcher \
        $pkgdir/usr/bin/quake4-dedicated

    # Install License (Quake 4)
    install -D -m 644 $pkgdir/opt/quake4/License.txt \
        $pkgdir/usr/share/licenses/quake4/License.txt

    # Install License (PunkBuster)
    install -D -m 644 $pkgdir/opt/quake4/pb/PBEULA.txt \
        $pkgdir/usr/share/licenses/quake4/PBEULA.txt

    # Install Desktop File
    install -D -m 644 $srcdir/quake4.desktop \
        $pkgdir/usr/share/applications/quake4.desktop

    # Install Icon File
    install -D -m 644 $pkgdir/opt/quake4/q4icon.bmp \
        $pkgdir/usr/share/pixmaps/quake4.bmp
}