blob: c92d66f47576da171bce5b091861b4295cd8664c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Chris Lane <aur at chrislane dot com>
pkgname=quassel-client-lighter-git
pkgver=0.14.pre.r110.g7c0eb011
pkgrel=1
pkgdesc="Qt-based distributed IRC client (client only) - minimal dependencies"
url='https://quassel-irc.org'
license=('GPL')
arch=('i686' 'x86_64' 'arm' 'aarch64')
depends=('qt5-base')
makedepends=('git' 'cmake' 'extra-cmake-modules' 'ninja' 'qt5-base' 'boost')
optdepends=('sonnet: spell checking support'
'hicolor-icon-theme: hicolor theme hierarchy support'
'libdbusmenu-qt5: dbus context menu for icon tray support')
provides=('quassel-client')
conflicts=('quassel-client')
source=("$pkgname"::"git+https://github.com/quassel/quassel")
md5sums=('SKIP')
_builddir="build"
pkgver() {
cd "$srcdir/$pkgname"
git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$pkgname"
rm -rf "$_builddir"
mkdir -p "$_builddir" && cd "$_builddir"
cmake -G Ninja \
-DWANT_MONO=OFF \
-DWANT_CORE=OFF \
-DWANT_QTCLIENT=ON \
-DHAVE_SSL=ON \
-DWITH_KDE=OFF \
-DUSE_QT5=ON \
-DWITH_WEBKIT=OFF \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
"$srcdir/$pkgname"
ninja
}
package() {
cd "$pkgname/$_builddir"
DESTDIR="$pkgdir" ninja install
}
# vim:set ts=2 sw=2 et:
|