summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 347323fad210404fd25a10ca3ee24b84f242b7e5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Maintainer: Chris Lane <aur at chrislane dot com>
pkgname=quassel-core-lighter-git
pkgver=0.14.pre.r130.g01d67be2
pkgrel=1
pkgdesc="Qt-based distributed IRC client (core only) - minimal dependencies"
url='https://quassel-irc.org'
license=('GPL')
arch=('i686' 'x86_64' 'arm' 'aarch64')
depends=('qt5-script')
makedepends=('git' 'extra-cmake-modules' 'ninja' 'boost')
optdepends=('qca: encryption support'
            'libldap: LDAP support'
            'qt5-tools: translations support')
provides=('quassel-core')
conflicts=('quassel-core')
source=("$pkgname"::"git+https://github.com/quassel/quassel")
md5sums=('SKIP')

_builddir="build"

pkgver() {
  cd "$srcdir/$pkgname"
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$pkgname"

  rm -rf "$_builddir"
  mkdir -p "$_builddir" && cd "$_builddir"

  cmake -G Ninja                  \
    -DWANT_MONO=OFF             \
    -DWANT_CORE=ON              \
    -DWANT_QTCLIENT=OFF         \
    -DHAVE_SSL=ON               \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib  \
    -DUSE_QT5=ON                \
    "$srcdir/$pkgname"

  ninja
}

package() {
  cd "$pkgname/$_builddir"

  DESTDIR="$pkgdir" ninja install
}

# vim:set ts=2 sw=2 et: