blob: 44a99e591444af13079016ea3eca8935163cba67 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright (C) 2020 Matthew "strager" Glazar
# See end of file for extended copyright information.
# Maintainer: Matthew "strager" Glazar <strager.nds@gmail.com>
# Contributor: Shivam Mehta <sm.cse at gmail dot com>
pkgname=quick-lint-js
pkgver=2.2.0
pkgrel=1
pkgdesc="Find bugs in JavaScript programs"
arch=(aarch64 arm armv6h armv7h i686 pentium4 x86_64)
url="https://quick-lint-js.com/"
license=(Apache Boost GPL3)
depends=(gcc-libs)
makedepends=(cmake gcc ninja)
checkdepends=(icu)
provides=()
conflicts=(quick-lint-js)
source=(
"${pkgname}-${pkgver}.tar.gz::https://c.quick-lint-js.com/releases/${pkgver}/source/quick-lint-js-${pkgver}.tar.gz"
"${pkgname}-${pkgver}.tar.gz.asc::https://c.quick-lint-js.com/releases/${pkgver}/source/quick-lint-js-${pkgver}.tar.gz.asc"
)
sha512sums=('5ef9a139aeaf45163509c9cd72f6a2c3d108aecbdb265df2afabfdacf6540ff8fe00b4f17e6824014135e82b98631be8693f285628baa2ca4433418a7ca0e7be'
'SKIP')
# Matthew "strager" Glazar (quick-lint-js signing key) <strager.nds@gmail.com>
validpgpkeys=(0327DE8F9CEF499851D19F6ED20BA9DCCF0E9D20)
build() {
cd "${pkgname}-${pkgver}"
cmake -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_BUILD_WITH_INSTALL_RPATH=YES \
-DCMAKE_INSTALL_PREFIX=/usr \
-DQUICK_LINT_JS_INSTALL_LICENSES_DIR="share/licenses/${pkgname}" \
-S . -B build
ninja -C build
}
check() {
cd "${pkgname}-${pkgver}"
ninja -C build test
}
package() {
cd "${pkgname}-${pkgver}"
DESTDIR="${pkgdir}/" ninja -C build install
}
# quick-lint-js finds bugs in JavaScript programs.
# Copyright (C) 2020 Matthew "strager" Glazar
#
# This file is part of quick-lint-js.
#
# quick-lint-js is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# quick-lint-js is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with quick-lint-js. If not, see <https://www.gnu.org/licenses/>.
|