blob: ad9cc77dd16d88fb8ae2cead37dc80895cb4f8c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright (C) 2020 Matthew Glazar
# See end of file for extended copyright information.
# Maintainer: Matthew "strager" Glazar <strager.nds@gmail.com>
# Contributor: Shivam Mehta <sm.cse at gmail dot com>
pkgname=quick-lint-js
pkgver=0.2.0
pkgrel=1
pkgdesc="Find bugs in JavaScript programs"
arch=(aarch64 arm armv6h armv7h i686 pentium4 x86_64)
url="https://quick-lint-js.com/"
license=(Apache Boost GPL3)
depends=(gcc-libs)
makedepends=(cmake ninja)
checkdepends=(icu)
provides=()
conflicts=(quick-lint-js)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/quick-lint/${pkgname}/archive/refs/tags/${pkgver}.tar.gz")
sha512sums=('dddc90c73ffb5b35473d477a2758d73e6ad84810085139393dc55a6ccc39d3138aeea742f41eaa8ffd308dc189e1d28e0724c1601ee4e752706c47c63c697244')
build() {
cd "${pkgname}-${pkgver}"
cmake -G Ninja \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DQUICK_LINT_JS_INSTALL_LICENSES_DIR="share/licenses/${pkgname}" \
-S . -B build
ninja -C build
}
check() {
cd "${pkgname}-${pkgver}"
ninja -C build test
}
package() {
cd "${pkgname}-${pkgver}"
DESTDIR="${pkgdir}/" ninja -C build install
# TODO(strager): Remove the following after releasing a new version:
mkdir -p "${pkgdir}/usr/share/licenses/${pkgname}/"
mv "${pkgdir}/usr/share/doc/quick-lint-js/copyright" "${pkgdir}/usr/share/licenses/${pkgname}/copyright"
rmdir "${pkgdir}/usr/share/doc/quick-lint-js/"
rmdir "${pkgdir}/usr/share/doc/"
}
# quick-lint-js finds bugs in JavaScript programs.
# Copyright (C) 2020 Matthew Glazar
#
# This file is part of quick-lint-js.
#
# quick-lint-js is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# quick-lint-js is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with quick-lint-js. If not, see <https://www.gnu.org/licenses/>.
|