blob: be1411388b112a6a2d6ee8b2ea507573d5182858 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Maintainer: Butui Hu <hot123tea123@gmail.com>
_pkgname=QuPath
pkgname=qupath
pkgver=0.5.1
pkgrel=1
pkgdesc='Bioimage analysis & digital pathology'
arch=('x86_64')
url='https://github.com/qupath/qupath'
license=('GPL-2.0-or-later')
depends=(
freetype2
gcc-libs
glibc
giflib
harfbuzz
lcms2
libjpeg-turbo
libpng
zlib
)
makedepends=(
'gendesk'
'gradle'
'java-environment=17'
)
optdepends=(
'ttf-droid: font for CJK characters'
)
options=(!strip)
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/qupath/qupath/archive/v${pkgver}.tar.gz")
sha512sums=('667ebb7d1e806f9c14c65db40b3baefd9816f48b0ce7ce0dddf53af46deaa25ad7656ba4369b4175ea03b709911fcbde6867247278d1527fab7919e1bc77e6f2')
prepare() {
echo "Creating desktop file"
gendesk -f -n --pkgname ${pkgname} \
--pkgdesc "${pkgdesc}" \
--categories "Graphics;MedicalSoftware;Science;" \
--icon "/opt/${_pkgname}/lib/${_pkgname}.png" \
--exec "${pkgname}"
}
build() {
cd "${pkgname}-${pkgver}"
# you could also build it with gradle wrapper
# ./gradlew clean jpackage
gradle clean jpackage -Porg.gradle.java.home=/usr/lib/jvm/default
}
package() {
install -d ${pkgdir}/opt
cp -a ${srcdir}/${pkgname}-${pkgver}/build/dist/${_pkgname} ${pkgdir}/opt/${_pkgname}
install -d "${pkgdir}/usr/bin"
ln -sf "/opt/${_pkgname}/bin/${_pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
}
# vim:set ts=2 sw=2 et:
|