blob: 8d303f81b21b35988ccc83f02c00583fbfb9760a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
# vim: set ts=2 sw=2 et ft=sh:
pkgname=qutebrowser-git
pkgver=1.4.0.r3.gae32b79d5
pkgrel=1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5"
arch=(any)
url="http://www.qutebrowser.org/"
license=('GPL')
depends=('python' 'python-setuptools' 'python-pyqt5' 'qt5-base'
'qt5-webengine' 'qt5-declarative' 'python-pypeg2' 'python-jinja'
'python-pygments' 'python-yaml' 'python-attrs')
makedepends=('asciidoc' 'pygmentize' 'git')
optdepends=(
'qt5-webkit: To use the QtWebKit backend'
'gst-libav: media playback with QtWebKit'
'gst-plugins-base: media playback with QtWebKit'
'gst-plugins-good: media playback with QtWebKit'
'gst-plugins-bad: media playback with QtWebKit'
'gst-plugins-ugly: media playback with QtWebKit'
'pdfjs: Displaying PDF in-browser with QtWebKit'
)
options=(!emptydirs)
conflicts=('qutebrowser')
provides=('qutebrowser')
source=('git+https://github.com/qutebrowser/qutebrowser.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/qutebrowser"
# Minor releases are not part of the master branch
_tag=$(git tag --sort=v:refname | tail -n1)
printf '%s.r%s.g%s' "${_tag#v}" "$(git rev-list "$_tag"..HEAD --count)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/qutebrowser"
python scripts/asciidoc2html.py
a2x -f manpage doc/qutebrowser.1.asciidoc
python setup.py build
}
package() {
cd "$srcdir/qutebrowser"
python setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 doc/qutebrowser.1 "$pkgdir/usr/share/man/man1/qutebrowser.1"
install -Dm644 misc/qutebrowser.desktop \
"$pkgdir/usr/share/applications/qutebrowser.desktop"
for i in 16 24 32 48 64 128 256 512; do
install -Dm644 "icons/qutebrowser-${i}x$i.png" \
"$pkgdir/usr/share/icons/hicolor/${i}x$i/apps/qutebrowser.png"
done
install -Dm644 icons/qutebrowser.svg \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/qutebrowser.svg"
install -dm755 "$pkgdir/usr/share/qutebrowser/userscripts"
find misc/userscripts -type f -exec install -m755 {} "$pkgdir/usr/share/qutebrowser/userscripts" \;
}
|