blob: 1615c3aa3002e9ed2d00d0e586db0965f921a8b7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
# Contributor: Morten Linderud <foxboron@archlinux.org>
# Contributor: Pierre Neidhardt <ambrevar@gmail.com>
# vim: set ts=4 sw=4 et ft=sh:
pkgname=qutebrowser-qt6-git
pkgver=2.5.4.r978.g346a39ba1
pkgrel=1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 (Qt 6 branch)"
arch=("any")
url="https://www.qutebrowser.org/"
license=("GPL")
depends=("python-jinja" "python-pyqt6" "python-yaml" "python-pyqt6-webengine")
makedepends=("asciidoc" "pygmentize" "git" "python-setuptools")
optdepends=("python-adblock: ABP-style adblocking"
"pdfjs: displaying PDF in-browser")
options=(!emptydirs)
conflicts=('qutebrowser' 'qutebrowser-git')
provides=('qutebrowser')
source=('git+https://github.com/qutebrowser/qutebrowser.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/qutebrowser"
# Minor releases are not part of the master branch
_tag=$(git tag --sort=v:refname | tail -n1)
printf '%s.r%s.g%s' "${_tag#v}" "$(git rev-list "$_tag"..HEAD --count)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "$srcdir/qutebrowser"
sed -i 's/_DEFAULT_WRAPPER = "PyQt5"/_DEFAULT_WRAPPER = "PyQt6"/' qutebrowser/qt/machinery.py
}
build() {
cd "$srcdir/qutebrowser"
python scripts/asciidoc2html.py
a2x -f manpage doc/qutebrowser.1.asciidoc
python setup.py build
}
package() {
cd "$srcdir/qutebrowser"
make -f misc/Makefile DESTDIR="$pkgdir" PREFIX=/usr install
}
|