blob: 1bf571ea5fb07c046052229f17e173b315392d34 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Florian Bruhin (The Compiler) <archlinux.org@the-compiler.org>
# vim: set ts=2 sw=2 et ft=sh:
pkgname=qutebrowser-git
pkgver=0.11.0.r334.ga942613d7
pkgrel=1
pkgdesc="A keyboard-driven, vim-like browser based on PyQt5 and QtWebKit"
arch=(any)
url="http://www.qutebrowser.org/"
license=('GPL')
depends=('python>=3.4' 'python-setuptools' 'python-pyqt5>=5.2' 'qt5-base>=5.2'
'qt5-webkit' 'qt5-declarative' 'libxkbcommon-x11' 'python-pypeg2'
'python-jinja' 'python-pygments' 'xdg-utils' 'desktop-file-utils'
'python-yaml' 'hicolor-icon-theme')
makedepends=('asciidoc' 'source-highlight' 'git')
optdepends=(
'gst-libav: media playback'
'gst-plugins-base: media playback'
'gst-plugins-good: media playback'
'gst-plugins-bad: media playback'
'gst-plugins-ugly: media playback'
'pdfjs: Displaying PDF in-browser'
'qt5-webengine: To use --backend webengine'
)
options=(!emptydirs)
conflicts=('qutebrowser')
provides=('qutebrowser')
source=('git+https://github.com/qutebrowser/qutebrowser.git')
sha256sums=('SKIP')
pkgver() {
cd "$srcdir/qutebrowser"
# Minor releases are not part of the master branch
_tag=$(git tag --sort=v:refname | tail -n1)
printf '%s.r%s.g%s' "${_tag#v}" "$(git rev-list "$_tag"..HEAD --count)" "$(git rev-parse --short HEAD)"
}
build() {
cd "$srcdir/qutebrowser"
python scripts/asciidoc2html.py
a2x -f manpage doc/qutebrowser.1.asciidoc
python setup.py build
}
package() {
cd "$srcdir/qutebrowser"
python setup.py install --root="$pkgdir/" --optimize=1
install -Dm644 doc/qutebrowser.1 "$pkgdir/usr/share/man/man1/qutebrowser.1"
install -Dm644 qutebrowser.desktop \
"$pkgdir/usr/share/applications/qutebrowser.desktop"
for i in 16 24 32 48 64 128 256 512; do
install -Dm644 "icons/qutebrowser-${i}x$i.png" \
"$pkgdir/usr/share/icons/hicolor/${i}x$i/apps/qutebrowser.png"
done
install -Dm644 icons/qutebrowser.svg \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/qutebrowser.svg"
install -dm755 "$pkgdir/usr/share/qutebrowser/userscripts"
find misc/userscripts -type f -exec install -m755 {} "$pkgdir/usr/share/qutebrowser/userscripts" \;
}
|