PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Vinícius dos Santos Oliveira <vini.ipsmaker@gmail.com>
pkgname=qwbfs
pkgver=1.2.6
pkgrel=1
pkgdesc="Cross platform WBFS file system manager"
arch=('i686' 'x86_64')
url="https://github.com/pasnox/qwbfsmanager"
license=('GPL2')
# Also 'openssl', but already satisfied:
depends=('qt5-base' 'hicolor-icon-theme')
makedepends=('git')
install=${pkgname}.install
source=("qwbfs::git+https://github.com/pasnox/qwbfsmanager.git#tag=v1.2.6"
        "fresh::git+https://github.com/pasnox/fresh.git#commit=264d665965c0f439bc91e7f51c31e2b76eea8753"
        "qmake-extensions::git+https://github.com/pasnox/qmake-extensions.git#commit=b60b99bccbfda40136c8aa1a54770543519feda8")
sha1sums=('SKIP' 'SKIP' 'SKIP')

prepare() {
  cd "$srcdir/qwbfs"
  git submodule init
  git config submodule.fresh.git.url "$srcdir/fresh"
  git submodule update

  cd "fresh.git"
  git submodule init
  git config submodule.qmake-extensions.git.url "$srcdir/qmake-extensions"
  git submodule update
}

build() {
  cd "$srcdir/qwbfs"

  qmake PREFIX=/usr
  make
}

package() {
  cd "$srcdir/qwbfs"

  mkdir -p "$pkgdir/usr/bin"
  cp bin/qwbfsmanager "$pkgdir/usr/bin"

  mkdir -p "$pkgdir/usr/share/applications"
  cp packages/QWBFSManager.desktop "$pkgdir/usr/share/applications"

  mkdir -p "$pkgdir/usr/share/icons/hicolor/512x512/apps"
  cp qwbfs/resources/qwbfsmanager.png \
     "$pkgdir/usr/share/icons/hicolor/512x512/apps"
}