blob: d56ce5753025cd059041ce42d1ce2df42bacbcef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: myuki <mioki dot cinnamon650 at 8shield dot net>
_pkgname=qwen-code
pkgname=${_pkgname}-bin
_name=qwen
pkgver=0.25.1
pkgrel=1
pkgdesc="Open-source AI agent originally based on Gemini CLI by QwenLM"
arch=('x86_64' 'aarch64')
url="https://github.com/QwenLM/${_pkgname}"
license=('Apache-2.0')
depends=('nodejs>=22.0.0' 'ripgrep')
optdepends=('xdg-utils: open links and launch browser integration'
'docker: run agent tools in a sandboxed container'
'podman: run agent tools in a sandboxed container'
'git: version control integrations')
provides=("$_pkgname" "${_name}")
conflicts=("$_pkgname" "${_name}")
source_x86_64=("${_pkgname}-${pkgver}-linux-x64.tar.gz::${url}/releases/download/v${pkgver}/${_pkgname}-linux-x64.tar.gz"
"system-defaults.json")
source_aarch64=("${_pkgname}-${pkgver}-linux-arm64.tar.gz::${url}/releases/download/v${pkgver}/${_pkgname}-linux-arm64.tar.gz"
"system-defaults.json")
b2sums_x86_64=('fdaef4131056a0060530f33fc07d3cea6227d1d1c5dcbf34c1905beea44aaa5ef25ee92c278d25025fd7573b0c494a43ef76507f47e7fe9be793c24ba0c76fbb'
'30c86151e58bd11bd1d39238646aae2dd8bc743ca2a03b64371a9dc36eae81c3acade6f39fe0235b0e7f8b059c7181d04ae5d134a3a316e0f9b3815b8f197bee')
b2sums_aarch64=('e89f816f0e1f948d1a8f7e1fad4f7c29237bec112b604f84a0f88ad323cd4fe84fdf1940c2a256673bed97caf95a52d5d961daa5791e2a87abe50d3c3aedc80a'
'30c86151e58bd11bd1d39238646aae2dd8bc743ca2a03b64371a9dc36eae81c3acade6f39fe0235b0e7f8b059c7181d04ae5d134a3a316e0f9b3815b8f197bee')
package() {
local appdir="${pkgdir}/usr/lib/${_pkgname}"
install -d "${appdir}" "${pkgdir}/usr/bin"
cp -a "${srcdir}/${_pkgname}/lib/." "${appdir}/"
sed -e '/^ROOT=/d' \
-e 's|"$ROOT/node/bin/node"|/usr/bin/node|g' \
-e "s|\"\$ROOT/bin/qwen\"|\"/usr/bin/${_name}\"|g" \
-e "s|\"\$ROOT/lib/|\"/usr/lib/${_pkgname}/|g" \
"${srcdir}/${_pkgname}/bin/qwen" > "${pkgdir}/usr/bin/${_name}"
chmod 755 "${pkgdir}/usr/bin/${_name}"
if grep -q 'ROOT' "${pkgdir}/usr/bin/${_name}"; then
echo "ERROR: Unhandled ROOT references in the startup script!" >&2
return 1
fi
rm -rf "${appdir}/vendor/ripgrep"
rm -f "${appdir}/LICENSE"
rm -f "${appdir}/README.md"
install -Dm644 -t "${pkgdir}/usr/share/licenses/${pkgname}" "${srcdir}/${_pkgname}/LICENSE"
install -Dm644 -t "${pkgdir}/usr/share/doc/${pkgname}" "${srcdir}/${_pkgname}/README.md"
install -Dm644 -t "${pkgdir}/etc/qwen-code" "system-defaults.json"
}
|