blob: 922084cb6df514db22726aabc3b50b0570bd8c6f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=alabaster.string
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Save and Load Biostrings to/from File"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
r-alabaster.base
r-biostrings
r-s4vectors
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-knitr
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('40407640753273dadcc3d008a65691a2')
b2sums=('2173ae7421d562f6d6dfac0364dbf43eb9ac9a21e821d6e66496f428aa69a1192bbaa3afcd855c23fcb8a9e838fe7643e31c0d82ec73a5a88d727a7570b6c9bf')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|