blob: 9cb4bec71315f2fa3d917e4b567767d292e4e02f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: peippo <christoph+aur@christophfink.com>
_cranname=anytime
_cranver=0.3.9
pkgname=r-${_cranname,,}
pkgdesc="Anything to ‘POSIXct’ or ‘Date’ Converter"
url="https://cran.r-project.org/package=${_cranname}"
license=("MIT")
pkgver=${_cranver//[:-]/.}
pkgrel=1
arch=("i686" "x86_64")
depends=(
"r>=3.2.0"
"r-bh"
"r-rcpp>=0.12.9"
)
optdepends=(
"r-gettz"
)
checkdepends=(
"${optdepends[@]}"
"texlive-core"
"r-tinytest"
)
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
b2sums=("867cca7faadc29cb99e4ae8428eabd0e3fa00e1c1f0553d3a0d8275c5526743a11dff340b1cacac3ae03bc294f2c9968110234d55e99a6ebc43c7bf413c0b58f")
build() {
mkdir -p "${srcdir}/build/"
R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}/build/"
}
check() {
R_LIBS="build/" R CMD check --no-manual --as-cran "${_cranname}"
}
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "${srcdir}/build/${_cranname}" "${pkgdir}/usr/lib/R/library"
if [[ -f "${_cranname}/LICENSE" ]]; then
install -Dm0644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
fi
}
|