blob: a507411357e5038506c85e472caf3700fa5d9cb0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=crisprBase
_pkgver=1.6.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=3
pkgdesc="Base functions and classes for CRISPR gRNA design"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
r-biocgenerics
r-biostrings
r-genomicranges
r-iranges
r-s4vectors
r-stringr
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-knitr
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('20cc1254ee7d33a966bb795f09f8be44')
b2sums=('61d2bd26b66656e1f035c94d1b8399126f7e1a99e00b469d9156a90270a5e085aab3e21f13ddbc98a074358dc1112db78ab43fdf2bc13e56e7f423b1ff8fae0f')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|