blob: c09057b59e081a9db6cd0c788e5e60f85dd97e4c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=cytoviewer
_pkgver=1.0.1
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="An interactive multi-channel image viewer for R"
arch=(any)
url="https://bioconductor.org/packages/${_pkgname}"
license=(GPL3)
depends=(
r-archive
r-colourpicker
r-cytomapper
r-ebimage
r-rcolorbrewer
r-s4vectors
r-shiny
r-shinycssloaders
r-shinydashboard
r-singlecellexperiment
r-summarizedexperiment
r-svglite
r-svgpanzoom
r-viridis
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-knitr
r-markdown
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('b8b7be3fc0bb988e39029fe1848b4a7a')
sha256sums=('d47d69ea1417a862420357514d8f607dcc9ab023ab88475a1369c7fec0e56fb2')
build() {
mkdir -p build
R CMD INSTALL "$_pkgname" -l build
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|