blob: 9633ea160b8de82ab8e636f2cda0c116ae543d6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=DelayedRandomArray
_pkgver=1.12.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Delayed Arrays of Random Values"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('GPL-3.0-only')
depends=(
r-delayedarray
r-dqrng
r-rcpp
)
makedepends=(
r-bh
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-knitr
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('8a190e38a3031fac8f604271d44354f7')
b2sums=('c9fecaa84293a3c78ad6ebad42c72216613df13f15b48f71e37c064a4cfbaa60d78acaa22c770e22d6d400d13e019172ef19952fe837b3aa75284512d573640b')
prepare() {
# fix test
sed -i '/recycle_vector(X, 100/ s/list(NULL, NULL)/list(NULL)/' \
"$_pkgname/tests/testthat/test-recycle.R"
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|