blob: e60848b7ca3f4f76c19cf72b2140beb214bfe40f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
_cranname=fontawesome
_cranver=0.5.0
pkgname=r-${_cranname,,}
pkgver=${_cranver//[:-]/.}
pkgrel=1
pkgdesc="Easily Work with 'Font Awesome' Icons"
arch=(any)
url="https://cran.r-project.org/package=${_cranname}"
license=(MIT)
depends=(r-rlang r-htmltools ttf-font-awesome)
checkdepends=(r-dplyr r-testthat)
optdepends=(
r-covr
r-dplyr
r-knitr
r-testthat
r-rsvg
)
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz"
"CRAN-MIT-TEMPLATE::https://cran.r-project.org/web/licenses/MIT")
sha256sums=('4117b417a33e82d626881d7059eb54e7534cba202e75dae7e27021cb3796e90b'
'e76e4aad5d3d9d606db6f8c460311b6424ebadfce13f5322e9bae9d49cc6090b')
build() {
mkdir -p build
R CMD INSTALL "${_cranname}" -l "${srcdir}/build"
}
check() {
cd "${_cranname}/tests"
R_LIBS="${srcdir}/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "build/${_cranname}" "${pkgdir}/usr/lib/R/library"
install -Dm644 CRAN-MIT-TEMPLATE "${pkgdir}/usr/share/licenses/${pkgname}/MIT"
install -Dm644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
# symlink TTF fonts to ttf-font-awesome package
cd "$pkgdir/usr/lib/R/library/$_cranname/fontawesome/webfonts"
local _font
for _font in *.ttf; do
ln -sf "/usr/share/fonts/TTF/$_font"
done
}
|