blob: 5634d78c01a1fc6097d35217e4dff454515902f3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=ggkegg
_pkgver=1.2.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="KEGG pathway visualization by ggplot2"
arch=(any)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
r-annotationdbi
r-biocfilecache
r-data.table
r-dplyr
r-getoptlong
r-ggplot2
r-ggraph
r-gtable
r-igraph
r-magick
r-org.hs.eg.db
r-patchwork
r-shadowtext
r-stringr
r-tibble
r-tidygraph
r-xml
)
checkdepends=(
r-testthat
)
optdepends=(
r-biocstyle
r-bnlearn
r-clusterprofiler
r-knitr
r-rmarkdown
r-testthat
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('dc286e42c2efa37d09ebac61f0a97c53')
b2sums=('0ad0dd4e72011147530eb37e7a64151f67ce385afffb8d0c7b810565737164f9fc3e350730cb51430abf5d30bec55fb02829178eb9ae393dadecc57216935e37')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|