blob: 11d5b8e983f39d668504b0e565e9a0636aae47de (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
# Contributor: frichtlm <frichtlm@gmail.com>
# Contributor: wagnerflo <florian@wagner-flo.net>
# Contributor: Tobias Neumann <mail at tobias dash neumann dot eu>
# Contributor: Nick B <Shirakawasuna at gmail _dot_com>
_pkgname=ggplot2
_pkgver=3.5.1
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Create Elegant Data Visualisations Using the Grammar of Graphics"
arch=(any)
url="https://cran.r-project.org/package=$_pkgname"
license=('MIT')
depends=(
r-cli
r-glue
r-gtable
r-isoband
r-lifecycle
r-rlang
r-scales
r-tibble
r-vctrs
r-withr
)
checkdepends=(
r-hexbin
r-mapproj
r-quantreg
r-sf
r-sp
r-svglite
r-testthat
r-xml2
ttf-font
)
optdepends=(
r-covr
r-dplyr
r-ggplot2movies
r-hexbin
r-hmisc
r-knitr
r-mapproj
r-maps
r-multcomp
r-munsell
r-profvis
r-quantreg
r-ragg
r-rcolorbrewer
r-rmarkdown
r-sf
r-svglite
r-testthat
r-vdiffr
r-xml2
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('f2add92370293ac6078f1963427d6ab2')
b2sums=('6082e08ffed5d945d444890c5ef6084ed477a4e7db70c23a02ff0664571a7ca8d1c74c06c77a3aff5ff6913505ab5a6cf116f310ab78d7c3d63583c948587b78')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|