blob: a6bebf7aa33c2f74d75496c683708a6594dacac9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=hdf5r
_pkgver=1.3.9
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Interface to the 'HDF5' Binary Data Format"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=(Apache)
depends=(
hdf5
r-bit64
r-r6
)
checkdepends=(
r-testthat
)
optdepends=(
r-formatr
r-knitr
r-nycflights13
r-reshape2
r-rmarkdown
r-testthat
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('68c60386888550ba88ef5168becca044')
b2sums=('56306a4dafa664fb5e789c9c9998c69627bc68d0803beee925fd92e07c13556512b08656b6c982b61e1906469d09e90b5eeb5ce00f36ddb89ac31952a9010d47')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|