blob: 994fba43442fe6f4e024a2d3141dd7555baa549b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: peippo <christoph+aur@christophfink.com>
_cranname=odbc
_cranver=1.4.2
pkgname=r-${_cranname,,}
pkgdesc="Connect to ODBC Compatible Databases (using the DBI Interface)"
url="https://cran.r-project.org/package=${_cranname}"
license=("MIT")
pkgver=${_cranver//[:-]/.}
pkgrel=1
arch=("i686" "x86_64")
depends=(
"r>=3.6.0"
"r-bit64"
"r-blob>=1.2.0"
"r-dbi>=1.1.0"
"r-hms"
"r-lifecycle"
"r-rcpp>=0.12.11"
"r-rlang>=0.2.0"
"unixodbc"
)
makedepends=(
"r-cpp11"
)
optdepends=(
"r-covr"
"r-dbitest"
"r-magrittr"
"r-rmarkdown"
"r-rsqlite"
"r-tibble"
"r-withr"
)
checkdepends=(
"${optdepends[@]}"
"r-testthat>=3.0.0"
)
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
b2sums=("98d66e38d316637ad15014dc0af29ee8e7efe1d400e30fd699f8917c7d4a731f04c32594b737f2098f6b672a0b3ff218c69a23985804d09003cc73272c0be120")
build() {
mkdir -p "${srcdir}/build/"
R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}/build/"
}
check() {
export R_LIBS="build/"
R CMD check --no-manual "${_cranname}"
}
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "${srcdir}/build/${_cranname}" "${pkgdir}/usr/lib/R/library"
if [[ -f "${_cranname}/LICENSE" ]]; then
install -Dm0644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
fi
}
|