blob: ca39231ef82d3b10e0148a0b04ad2df1d2ca95a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
_cranname=processx
_cranver=3.5.2
pkgname=r-${_cranname,,}
pkgver=${_cranver//[:-]/.}
pkgrel=2
pkgdesc="Execute and Control System Processes"
arch=(i686 x86_64)
url="https://cran.r-project.org/package=${_cranname}"
license=(MIT)
depends=(r r-ps r-r6)
checkdepends=(r-curl r-testthat)
optdepends=(
r-callr
r-cli
r-codetools
r-covr
r-curl
r-debugme
r-testthat
r-withr
)
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz"
"error-test.patch::https://github.com/r-lib/processx/pull/321.patch"
"R-MIT-TEMPLATE::https://cran.r-project.org/web/licenses/MIT")
sha256sums=('ed6f2d1047461c6061e6ed58fb6de65a289b56009867892abad76c6bba46fc2b'
'9f55e81165f3bf09be189d683017fce3b0cc5f39687b5b23c88fd401b7a82758'
'e76e4aad5d3d9d606db6f8c460311b6424ebadfce13f5322e9bae9d49cc6090b')
prepare() {
cd "${_cranname}"
# Fix two tests that don't work with a non-English locale
patch -Np1 -i "${srcdir}/error-test.patch"
}
build() {
mkdir -p build
R CMD INSTALL "${_cranname}" -l "${srcdir}/build"
}
check() {
cd "${_cranname}/tests"
R_LIBS="${srcdir}/build" NOT_CRAN=true R --vanilla -q -f testthat.R
}
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "build/${_cranname}" "${pkgdir}/usr/lib/R/library"
install -Dm644 R-MIT-TEMPLATE "${pkgdir}/usr/share/licenses/${pkgname}/MIT"
install -Dm644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|