blob: 9abf6167ab8c148be89118f49886a07980379515 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
_pkgname=puma
_pkgver=3.44.0
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=3
pkgdesc="Propagating Uncertainty in Microarray Analysis(including Affymetrix tranditional 3' arrays and exon arrays and Human Transcriptome Array 2.0)"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('LGPL-2.0-or-later')
depends=(
r-affy
r-affyio
r-biobase
r-mclust
r-oligo
r-oligoclasses
)
optdepends=(
r-affydata
r-annotate
r-limma
r-pumadata
r-rocr
r-snow
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz"
"fix-lto.patch")
md5sums=('ed1d90c9c9b7751611b0f32edf0a1ffb'
'885d25cbb9335808ed144d24c323737c')
b2sums=('a65d82535762b7ee885e993c8421f0bbe23d6dddf6608b9d0c11140e19f9894fda612988fdcfd892b9404d74012b7237098774f0da3a0e14ef770ef82fac5b39'
'f896fbaf21a3812527640043cb322e51ca2d4365306619deba7dcbd3f47ed0d68656c898dd84a69ad32dd8823c8e00ec93eef877e49f9b0d0816de9607a38b04')
prepare() {
# fix compiling with lto
patch -Np1 -i fix-lto.patch
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|