blob: 96ae2fa141820e9aaa30c5e57f69b2363a75d59b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: peippo <christoph+aur@christophfink.com>
# Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
# Contributor: Grey Christoforo <first name at last name dot net>
_cranname=R6
_cranver=2.5.1
pkgname=r-${_cranname,,}
pkgdesc="Encapsulated Classes with Reference Semantics"
url="https://cran.r-project.org/package=${_cranname}"
license=("MIT")
pkgver=${_cranver//[:-]/.}
pkgrel=3
arch=("any")
depends=(
"r>=3.0"
)
optdepends=(
"r-pryr"
)
checkdepends=(
"${optdepends[@]}"
"r-testthat"
)
source=("https://cran.r-project.org/src/contrib/${_cranname}_${_cranver}.tar.gz")
b2sums=("0045d7c37dfb7a773cd24e85e695575eaf6aa5c9392fb6888c10aa9fb3e35b13a230ed0aabcf84d52e656ef506ab58371044c4179b3380f5324b217fae6daeb4")
build() {
mkdir -p "${srcdir}/build/"
R CMD INSTALL ${_cranname}_${_cranver}.tar.gz -l "${srcdir}/build/"
}
check() {
cd "${srcdir}/${_cranname}/tests"
R_LIBS="${srcdir}/build/" Rscript --vanilla testthat.R
}
package() {
install -dm0755 "${pkgdir}/usr/lib/R/library"
cp -a --no-preserve=ownership "${srcdir}/build/${_cranname}" "${pkgdir}/usr/lib/R/library"
if [[ -f "${_cranname}/LICENSE" ]]; then
install -Dm0644 "${_cranname}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
fi
}
|