blob: 1f281cee1925ceaef546250a58b55641e205de3d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
# Contributor: Robert Greener <me@r0bert.dev>
_pkgname=reticulate
_pkgver=1.36.1
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Interface to 'Python'"
arch=(x86_64)
url="https://cran.r-project.org/package=$_pkgname"
license=('Apache-2.0')
depends=(
python
r-here
r-jsonlite
r-png
r-rappdirs
r-rcpp
r-rcpptoml
r-rlang
r-withr
)
checkdepends=(
ipython
python-docutils
python-matplotlib
python-numpy
python-pandas
python-pipenv
python-plotly
python-poetry
python-scipy
python-tabulate
python-wrapt
r-rmarkdown
r-testthat
)
optdepends=(
"ipython: IPython console app"
"python-numpy: translation between R matrices and NumPy arrays"
r-callr
r-cli
r-glue
r-knitr
r-pillar
r-rmarkdown
r-testthat
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('b9317e83a7c0ad73ab75dd14f4731cec')
b2sums=('0ae858af7a6d43f26e783d2089a8631c86a6ad4a45b9debc488320107aa8cabd881b238a98d71f6e0541e39e2bbbf04afd6033ec036b0c9b8760d084eef5cee4')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
# compile python bytecode
python -m compileall -o 0 -o 1 -s build -p /usr/lib/R/library "build/$_pkgname/python/rpytools"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|