blob: 3e556fb892eba2803f964f98d8833a0430f123df (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
# Contributor: anzi2001 <anzi2001 at gmail dot com>
# Contributor: haha662 <haha662 at outlook dot com>
# Contributor: Kibouo <csonka.mihaly@hotmail.com>
# Contributor: Ward Segers <w@rdsegers.be>
# Contributor: Alex Branham <branham@utexas.edu>
_pkgname=rmarkdown
_pkgver=2.26
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Dynamic Documents for R"
arch=(any)
url="https://cran.r-project.org/package=$_pkgname"
license=('GPL-3.0-only')
depends=(
pandoc
r-bslib
r-evaluate
r-fontawesome
r-htmltools
r-jquerylib
r-jsonlite
r-knitr
r-tinytex
r-xfun
r-yaml
)
checkdepends=(
r-curl
r-shiny
r-testthat
texlive-basic
texlive-fontsrecommended
texlive-latexextra
)
optdepends=(
r-cleanrmd
r-digest
r-downlit
r-dygraphs
r-fs
r-katex
r-rsconnect
r-sass
r-shiny
r-testthat
r-tibble
r-vctrs
r-withr
)
source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('d4f5e42ce1e7d2ab04fb1beff82c4ff5')
b2sums=('787c2e0505c07345cc1e20826ca1a85d8fabc58a0468f76d7fb0e5d2a555168913afa0fca38fad5d7359c1fb6f0bcb44fdddbd9f2686a828c0e7d8f3818f829f')
prepare() {
# Skip a test that might fail depending on environment
sed -i '/"Converting bib file is working"/a\ \ skip("Inconsistent test")' \
"$_pkgname/tests/testthat/test-pandoc.R"
}
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
}
|