blob: aa7951badad870db26258055444e116c9073bf87 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
_pkgname=simona
_pkgver=1.0.10
pkgname=r-${_pkgname,,}
pkgver=${_pkgver//-/.}
pkgrel=1
pkgdesc="Semantic Similarity in Bio-Ontologies"
arch=(x86_64)
url="https://bioconductor.org/packages/$_pkgname"
license=('MIT')
depends=(
java-runtime
perl
r-circlize
r-complexheatmap
r-getoptlong
r-globaloptions
r-igraph
r-matrixstats
r-polychrome
r-rcpp
r-s4vectors
r-shiny
r-xml2
)
checkdepends=(
r-go.db
r-org.hs.eg.db
r-proxyc
r-testthat
)
optdepends=(
r-annotationdbi
r-annotationhub
r-biocmanager
r-diagrammer
r-go.db
r-interactivecomplexheatmap
r-jsonlite
r-knitr
r-org.hs.eg.db
r-png
r-proxyc
r-ragg
r-simplifyenrichment
r-testthat
r-uniprotkeywords
)
source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
md5sums=('3c9d33cfa91dc8e3e071da9fb3bff761')
b2sums=('00f3ed8cce6c401558d4e08365ac82111a00fd7e8f973b438868d58e602efe90b13d528170da13c323d16a4d6eab32ad4445938027834a068ba29c9228656b14')
build() {
mkdir build
R CMD INSTALL -l build "$_pkgname"
}
check() {
cd "$_pkgname/tests"
R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla test-all.R
}
package() {
install -d "$pkgdir/usr/lib/R/library"
cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
install -d "$pkgdir/usr/share/licenses/$pkgname"
ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
}
|