PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Contributor: Paige Aran <paige.aran@gmail.com>
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>

pkgname=racket-git
pkgver=6.3.0.3.35632.6118997
pkgrel=1
pkgdesc="Minimal Racket installation, without useless DrRacket, from git"
arch=('i686' 'x86_64')
url="http://racket-lang.org/"
license=('LGPL')
depends=('bash' 'libffi')
makedepends=('git')
provides=('racket')
conflicts=('racket')
options=('!strip' '!emptydirs')
source=("git://github.com/plt/racket.git")
_gitname="racket"
md5sums=('SKIP')

pkgver() {
  cd $_gitname
  printf %s.%s.%s \
	 $(grep ' MZSCHEME_VERSION ' \
		${srcdir}/${_gitname}/${_gitname}/src/racket/src/schvers.h \
		| cut -d '"' -f 2) "$(git rev-list --count HEAD)" $(git log -1 --format='%h')
}

build() {
  cd ${srcdir}/${_gitname}/${_gitname}/src
  [[ -d build ]] || mkdir build
  cd build
  [[ "$CARCH" == "x86_64" ]] && export CFLAGS+=" -fPIC"
  ../configure --prefix=/usr --sysconfdir=/etc --enable-shared --disable-strip
  make
}

package() {
  cd ${srcdir}/${_gitname}/${_gitname}/src/build
  make DESTDIR="${pkgdir}" install
}