blob: 3dd2c5bdcde53a1594a66d24729d186ceabb04ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
pkgname="radarr"
pkgver=5.5.3.8819
pkgrel=1
pkgdesc="Movie download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Radarr/Radarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('sqlite')
optdepends=(
'sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'qbittorrent: torrent downloader'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'jackett: torrent indexer proxy'
'nzbhydra2: torznab and usenet indexer proxy'
'prowlarr: torrent and usenet indexer proxy'
'libgdiplus: provides a gdi+ compatible api'
)
source_x86_64=("https://github.com/Radarr/Radarr/releases/download/v${pkgver}/Radarr.master.${pkgver}.linux-core-x64.tar.gz")
source_aarch64=("https://github.com/Radarr/Radarr/releases/download/v${pkgver}/Radarr.master.${pkgver}.linux-core-arm64.tar.gz")
source_armv7h=("https://github.com/Radarr/Radarr/releases/download/v${pkgver}/Radarr.master.${pkgver}.linux-core-arm.tar.gz")
source=('radarr.service'
'radarr.tmpfiles'
'radarr.sysusers'
'package_info')
sha512sums=('64bfe917560e1de43b36a9c9bd2ac653f9fb231ed1971522b7b72ad308e72c9a29b5457aaa2faa84d1851148e5de9c707f43c81a42fcee40da98bf1d593c1928'
'2ef38a061f4438349f7dafe209328fe9de5f44712f16435805e2622050be45a3fffd1838d9fccef2d6aa7603cf05b01280df6fed957b66d2d67ceaeeedcd5f6f'
'c1ee3925eced182ea7fffa55a6dc2a4e099ccf18636fc237ef0a2fc9517a38cfc2a819ae5a7bc546b63e383506f9f47e89454a71e34106c579d7454d71b2299e'
'c5a3387a72b0ee51d111b351527f47c59a2000696d165d93ffa86d1e4c732aee3e156c4e9132517efe1c9804223b3a655f089e234ce0f0783f7d5877d1d6af86')
sha512sums_x86_64=('e224558e1b445e0ba420fe88d995132db0b99ecc8a89b393ce7dbe65e2605eaa25a7929294e67cf52e3bd9cc1b46eeee11b678b04eeef4d93ad4545f04d9e91d')
sha512sums_aarch64=('8433679b7d5e20c19848dc90f27319df70c2a2418c457599884c525db074c8451de66e58289a32d0784aeafebe621b5884183b8d19668828b3b6fffc5ae7c376')
sha512sums_armv7h=('6343bf4082b1056b4d1b9a8fff8c53d2d8166ef7a2463b6476043120f565aa74895c49ddb72b037b9496c2a85dcd6ef73f90f039352d6aaad2299dead0596674')
package() {
rm -rf "${srcdir}/Radarr/Radarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/radarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Radarr/"* "${pkgdir}/usr/lib/radarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/radarr/bin"
chmod +x "${pkgdir}/usr/lib/radarr/bin/Radarr" "${pkgdir}/usr/lib/radarr/bin/ffprobe"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/radarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/radarr/package_info"
install -D -m 644 "${srcdir}/radarr.service" "${pkgdir}/usr/lib/systemd/system/radarr.service"
install -D -m 644 "${srcdir}/radarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/radarr.conf"
install -D -m 644 "${srcdir}/radarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/radarr.conf"
}
|