blob: 6de727ec10e20111baecfd52bd6a19642496fc22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
pkgname="radarr-develop"
pkgver=4.1.0.6175
pkgrel=1
pkgdesc="Movie download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Radarr/Radarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('sqlite')
optdepends=('sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'jackett: torrent indexer proxy'
'libgdiplus: provides a gdi+ compatible api')
provides=('radarr' 'radarr-aphrodite')
conflicts=('radarr' 'radarr-aphrodite')
source_x86_64=("Radarr.develop.${pkgver}.linux-core-x64.tar.gz::https://radarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("Radarr.develop.${pkgver}.linux-core-arm64.tar.gz::https://radarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("Radarr.develop.${pkgver}.linux-core-arm.tar.gz::https://radarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('radarr.service'
'radarr.tmpfiles'
'radarr.sysusers'
'package_info')
sha512sums=('fa3829ed19801a212d389d902d385589553fe0b0d7920b57f5ebf12d6ffedcd30a58403d61845d5ecd63380c4264115827f7cd602295cb7648db6c5e71601575'
'2ef38a061f4438349f7dafe209328fe9de5f44712f16435805e2622050be45a3fffd1838d9fccef2d6aa7603cf05b01280df6fed957b66d2d67ceaeeedcd5f6f'
'c1ee3925eced182ea7fffa55a6dc2a4e099ccf18636fc237ef0a2fc9517a38cfc2a819ae5a7bc546b63e383506f9f47e89454a71e34106c579d7454d71b2299e'
'3ece517c026422dd9f6a8c20e8832021c12be4fa84c85ec0758adf4c955620d2b0e75ee534a09b0f87ab587b374fcd757c818c722d147fd6cc9065735d7d6e0f')
sha512sums_x86_64=('b3d88b2eb58a4b8125704299ddd9aaec306e9119eaffa142504e96d4d77ccefd77c226e24d6f32222811e5a0727194758940eae6890ad0927e2aa553777eaa60')
sha512sums_aarch64=('02ba1440fe09ef5fc43263cbdbd546218ba4f7167b596a56edd510d05f9db382e8aa5901ad32c851c488492323e1351446e34a01d5b75638015879b5f3a598f9')
sha512sums_armv7h=('13ef8a393c257a0bbd70c7b69ed9a768df69896e4d021af10262faea1508ec9ec9a129c9c9302bf6692ebadcdefb9270f8391668b09fbb16925f2c8ad6c24ab0')
package() {
rm -rf "${srcdir}/Radarr/Radarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/radarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Radarr/"* "${pkgdir}/usr/lib/radarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/radarr/bin"
chmod +x "${pkgdir}/usr/lib/radarr/bin/Radarr" "${pkgdir}/usr/lib/radarr/bin/ffprobe"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/radarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/radarr/package_info"
install -D -m 644 "${srcdir}/radarr.service" "${pkgdir}/usr/lib/systemd/system/radarr.service"
install -D -m 644 "${srcdir}/radarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/radarr.conf"
install -D -m 644 "${srcdir}/radarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/radarr.conf"
}
|