blob: d0cc56e7a87b4fb23a878a6873fa8ec64ee1efd6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://radarr.servarr.com/v1/update/nightly?version=0.0.0.0&os=linux&runtime=netcore&arch=x64
pkgname="radarr-nightly"
pkgver=3.0.0.3879
pkgrel=1
pkgdesc="Movie download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Radarr/Radarr"
license=('GPL3')
options=('!strip' 'staticlibs')
depends=('libmediainfo' 'sqlite')
optdepends=('sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'jackett: torrent indexer proxy'
'libgdiplus: provides a gdi+ compatible api')
provides=('radarr')
conflicts=('radarr')
source_x86_64=("Radarr.nightly.${pkgver}.linux-core-x64.tar.gz::https://radarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("Radarr.nightly.${pkgver}.linux-core-arm64.tar.gz::https://radarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("Radarr.nightly.${pkgver}.linux-core-arm.tar.gz::https://radarr.servarr.com/v1/update/nightly/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('radarr.service'
'radarr.tmpfiles'
'radarr.sysusers'
'package_info')
sha512sums=('b9725386f513db6e9cd2eaef33dc8b34b21e43faacd2c9e1c29df2e6acf8e6bbfcf055222b114c13e5d149166f6e3145ba0336502b6f4965554f14102425ef61'
'2ef38a061f4438349f7dafe209328fe9de5f44712f16435805e2622050be45a3fffd1838d9fccef2d6aa7603cf05b01280df6fed957b66d2d67ceaeeedcd5f6f'
'c1ee3925eced182ea7fffa55a6dc2a4e099ccf18636fc237ef0a2fc9517a38cfc2a819ae5a7bc546b63e383506f9f47e89454a71e34106c579d7454d71b2299e'
'1229427e6bc35c7d292385cd9965231c4f1933db1517060efddada08dbf1ce74fe01a494422da2696d8c7e5d58669573c31a04831ee2760204ab09a86bd94339')
sha512sums_x86_64=('2a0aebddfc3d45c22257aa089c83ca7604282d893b232daf5f0798fdee8dafb93a85df14e812ca752cdcb28126e69993ab5fd5e386ae0b26775bab9a2745a0ca')
sha512sums_aarch64=('514b04a5a46db5a1b6224d1ec220dc29a7ba20fa97f3dc72a41b212ff243dff028f52a6a53e5e2a1ac2add500ec3b7780af412e6ce92c19cfe3c53d0fb94375d')
sha512sums_armv7h=('6a04f5cf49a8df1be67020c56e19aa2a35fafdcaa00ad4b0b10c05440566f76c9fedb7a44b2bc8a7c051ba46ffd8efa1f6dddde6e9148cd444036241163ebece')
package() {
rm -rf "${srcdir}/Radarr/Radarr.Update"
install -d -m 755 "${pkgdir}/usr/lib/radarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Radarr/"* "${pkgdir}/usr/lib/radarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/radarr/bin"
chmod +x "${pkgdir}/usr/lib/radarr/bin/Radarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/radarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/radarr/package_info"
install -D -m 644 "${srcdir}/radarr.service" "${pkgdir}/usr/lib/systemd/system/radarr.service"
install -D -m 644 "${srcdir}/radarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/radarr.conf"
install -D -m 644 "${srcdir}/radarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/radarr.conf"
}
|