blob: 2247e1217035096a347732cd29070c8f438fe69f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Maintainer: Teteros <teteros at teknik dot io>
pkgname=radium-bin
pkgver=6.5.77
pkgrel=1
pkgdesc='A graphical music editor. A next generation tracker. (Demo Version)'
arch=(x86_64)
url=https://users.notam04.no/~kjetism/radium
license=(GPL2)
provides=(radium)
conflicts=(radium)
groups=(pro-audio)
depends=(
desktop-file-utils
glu
hicolor-icon-theme
jack2
libsm
libxcomposite
libxrender
shared-mime-info
ttf-bitstream-vera
)
optdepends=(
'new-session-manager: for session management'
'vst-plugins: more plugins'
)
options=(!strip)
source=("https://users.notam02.no/~kjetism/radium/demos/linux/radium_64bit_linux-$pkgver-demo.tar.xz")
sha256sums=('7960f334fb077651820ad15012495704f454162d0893a0416fddae8853ac398a')
package() {
cd radium_64bit_linux-$pkgver-demo
# Nouveau and AMD drivers require a newer libstdc++ than Radium provides so removing it is necessary to avoid crashes
rm lib/libstdc++.so.6
# Generate a dummy libselinux.so because official builds depend on it
# https://github.com/kmatheussen/radium/pull/1286#issuecomment-686697881
echo "extern int is_selinux_enabled(void){return 0;}" > selinux-dummy.c
gcc -s -shared -o lib/libselinux.so.1 selinux-dummy.c
rm selinux-dummy.c
# Copy radium files to a self-contained /opt prefix
mkdir -p "$pkgdir/opt/radium"
cp -a bin lib "$pkgdir/opt/radium"
# Recreate run_radium.sh
echo '#!/usr/bin/env bash' > "$pkgdir/opt/radium/run_radium.sh"
echo LD_LIBRARY_PATH='"/opt/radium/lib:$LD_LIBRARY_PATH"' QT_QPA_PLATFORM_PLUGIN_PATH=/opt/radium/bin/qt5_plugins \
/opt/radium/bin/radium '"$@"' >> "$pkgdir/opt/radium/run_radium.sh"
chmod +x "$pkgdir/opt/radium/run_radium.sh"
# Wrapper, Icons, .desktop and mimetype files
mkdir -p "$pkgdir/usr/bin" \
"$pkgdir/usr/share/icons/hicolor/"{16x16,32x32,128x128,256x256}"/apps" \
"$pkgdir/usr/share/applications" \
"$pkgdir/usr/share/mime/packages"
ln -s "/opt/radium/run_radium.sh" "$pkgdir/usr/bin/radium"
ln -s "/opt/radium/bin/radium_16x16x8.png" "$pkgdir/usr/share/icons/hicolor/16x16/apps/radium.png"
ln -s "/opt/radium/bin/radium_32x32x24.png" "$pkgdir/usr/share/icons/hicolor/32x32/apps/radium.png"
ln -s "/opt/radium/bin/radium_128x128x32.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/radium.png"
ln -s "/opt/radium/bin/radium_256x256x32.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/radium.png"
ln -s "/opt/radium/bin/radium.desktop" "$pkgdir/usr/share/applications/radium.desktop"
ln -s "/opt/radium/bin/radium-mimetype.xml" "$pkgdir/usr/share/mime/packages/radium.xml"
}
|