blob: 41aff4d4a4b30bf3947f429944607e9bef565748 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
|
# Maintainer: nyxkn <dev@nyxkn.net>
# Contributor: yustin <#archlinux-proaudio@libera.chat>
# Contributor: Teteros <teteros at teknik dot io>
# Contributor: Karol "Kenji Takahashi" Woźniak <kenji.sx>
# Contributor: Jakob Gahde <j5lx@fmail.co.uk>
_pkgname=radium
pkgname=$_pkgname-git
pkgver=7.4.76.r7.g0c86614
pkgrel=1
pkgdesc='A graphical music editor. A next generation tracker.'
arch=(x86_64)
url=https://users.notam02.no/~kjetism/radium
license=(GPL2)
groups=(pro-audio)
provides=(radium)
conflicts=(radium)
depends=(
desktop-file-utils
fftw
glu
gsfonts
hicolor-icon-theme
jack
liblo
liblrdf
libmpc
libsndfile
python2
qt5-svg
qt5-webkit
qt5-x11extras
speex
ttf-bitstream-vera
ttf-croscore
ttf-lato
libatomic_ops
libsamplerate
tk
guile
libxkbfile
openssl
ncurses
gmp
xcb-util-keysyms
mpfr
libmpc
libogg
libvorbis
openssl
alsa-lib
glib2
binutils
xorg-util-macros
qt5-base
libmicrohttpd
ladspa
)
makedepends=(
git
boost
cmake
libxcursor
libxinerama
libxrandr
qt5-tools
vst2sdk
gcc13
)
optdepends=(
'new-session-manager: for session management'
'calf-ladspa: default chorus plugin used in new file templates'
'ladspa-plugins: package group for plugins normally included in binary releases'
'vst-plugins: more plugins'
)
options=( !strip )
source=("git+https://github.com/kmatheussen/radium"
radium.install
build_linux_common.patch
)
sha256sums=('SKIP'
'f627730ff7a819e8cc5ac5c2b5f1fb2f2237327db6ea5442c55a23c1ce82ef14'
'SKIP'
)
install=radium.install
prepare() {
cd "$_pkgname"
export PATH=$(pwd):$PATH
# use gcc13 ...
ln -sf /usr/bin/cc-13 cc
ln -sf /usr/bin/gcc-13 gcc
ln -sf /usr/bin/c++-13 c++
ln -sf /usr/bin/g++-13 g++
export CC=gcc-13 CXX=g++-13
# fix for binutils 2.40
patch -p0 < "$srcdir/build_linux_common.patch"
# This tweak edits new file template and demo songs to be compatible with chorus plugin from calf-ladspa package
# New Demosong also needs fixes for LADSPA-Plugins
# !! NOTE TO LMMS USERS !!
# !! Comment next line out if you have LMMS installed as it already comes with their own version of Calf plugins !!
for file in bin/sounds/*.rad; do sed -i -e 's/Calf MultiChorus LADSPA/Calf Multi Chorus LADSPA/g' "$file"; done
for file in bin/sounds/*.RAD; do sed -i -e 's/Calf MultiChorus LADSPA/Calf Multi Chorus LADSPA/g' "$file"; done
sed -ie "s/C\* Eq - 10-band equalizer/C\* Eq10 - 10-band equaliser/g" bin/sounds/ROMANCE2.RAD
# See comment on calf-ladspa AUR page then on how to let Radium load Calf from LMMS package
sed -i "/cd libpd-master/s|$|\nsed -i '/LINUXCFLAGS/s/=/= --Wno-error=implicit-function-declaration/' pure-data/extra/makefile |" bin/packages/build.sh
sed -i "/cd libpd-master/s|$|\nsed -i '/define CFLAGS/s/-Wall/-Wall -Wno-error=implicit-function-declaration/' make.scm |" bin/packages/build.sh
}
pkgver() {
cd "$_pkgname"
git describe --long --abbrev=7 | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "$_pkgname"
export PATH=$(pwd):$PATH
export INCLUDE_FAUSTDEV_BUT_NOT_LLVM=1
RADIUM_QT_VERSION=5 RADIUM_VST2SDK_PATH=/usr/src/vst2sdk RADIUM_BUILD_LIBXCB=0 make packages
RADIUM_QT_VERSION=5 RADIUM_VST2SDK_PATH=/usr/src/vst2sdk BUILDTYPE=RELEASE ./build_linux.sh
}
package() {
cd "$_pkgname"
# Install radium and its packages to /opt
RADIUM_INSTALL_LIBXCB=0 ./install.sh "$pkgdir/opt"
# radium.install will link ladspa-path here so remove it
rm -rf $pkgdir/opt/radium/ladspa
# Create startup script according to bin/packages/README
mkdir -p "$pkgdir/usr/bin"
echo '#!/usr/bin/env bash' > "$pkgdir/usr/bin/radium"
echo QT_QPA_PLATFORM_PLUGIN_PATH="$($(RADIUM_QT_VERSION=5 ./find_moc_and_uic_paths.sh qmake) -query QT_INSTALL_PLUGINS)" \
/opt/radium/radium '"$@"' >> "$pkgdir/usr/bin/radium"
chmod +x "$pkgdir/usr/bin/radium"
# Icons, .desktop and mimetype files
mkdir -p "$pkgdir/usr/share/icons/hicolor/"{16x16,32x32,128x128,256x256}"/apps" \
"$pkgdir/usr/share/applications" \
"$pkgdir/usr/share/mime/packages"
ln -s "/opt/radium/radium_16x16x8.png" "$pkgdir/usr/share/icons/hicolor/16x16/apps/radium.png"
ln -s "/opt/radium/radium_32x32x24.png" "$pkgdir/usr/share/icons/hicolor/32x32/apps/radium.png"
ln -s "/opt/radium/radium_128x128x32.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/radium.png"
ln -s "/opt/radium/radium_256x256x32.png" "$pkgdir/usr/share/icons/hicolor/256x256/apps/radium.png"
ln -s "/opt/radium/radium.desktop" "$pkgdir/usr/share/applications/radium.desktop"
ln -s "/opt/radium/radium-mimetype.xml" "$pkgdir/usr/share/mime/packages/radium.xml"
}
warn_build_references() {
# Silence warning about build dir refs as Radium's author prefers packagers don't strip binaries.
# https://github.com/kmatheussen/radium/issues/1153#issuecomment-421543245
true
}
|