blob: 78de05a40615179bfd2f8ea66c7645c74d4b7c8d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=radvd-git
pkgver=2.17.r8.g7488976
pkgrel=1
pkgdesc="IPv6 router advertisement daemon"
arch=('i686' 'x86_64')
url="http://www.litech.org/radvd/"
license=('custom')
depends=('glibc')
makedepends=('git')
checkdepends=('check')
provides=('radvd')
conflicts=('radvd')
backup=('etc/radvd.conf')
source=("git+https://github.com/reubenhwk/radvd.git")
sha256sums=('SKIP')
pkgver() {
cd "radvd"
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
cd "radvd"
./autogen.sh
./configure --prefix="/usr" \
--sbindir="/usr/bin" \
--sysconfdir="/etc" \
--with-pidfile="/run/radvd.pid" \
--with-check
make
}
check() {
cd "radvd"
make check
}
package() {
cd "radvd"
make DESTDIR="$pkgdir" install
install -Dm644 "radvd.conf.example" "$pkgdir/etc/radvd.conf"
install -Dm644 "COPYRIGHT" "$pkgdir/usr/share/licenses/$pkgname/COPYRIGHT"
}
|