blob: 9dd1a0b068751ff2080b89a86ba2c9a3a3d77bcf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
# Maintainer: LightDot <lightdot -a-t- g m a i l>
# Contributor: samæ <samæ at marvid dot fr>
_name=raleway
_fname=Raleway
pkgbase=$_name-font
pkgname=(otf-$_name ttf-$_name ttf-$_name-variable)
pkgver=4.101
pkgrel=1
pkgdesc='An elegant sans-serif font family, now 9 weights and italic style'
arch=('any')
url="https://www.theleagueofmoveabletype.com/$_name"
license=('OFL')
groups=('lmt-fonts')
source=("https://github.com/theleagueof/$_name/releases/download/$pkgver/$_fname-$pkgver.tar.xz")
sha256sums=('523070d32418b4223e79f4629bf28b935723906d156d2e6af016e6a34fe6d3eb')
package_otf-raleway() {
provides=("$pkgbase" "otf-impallari-raleway-family")
conflicts=("otf-impallari-raleway-family")
replaces=("otf-impallari-raleway-family")
cd "$_fname-$pkgver"
install -Dm644 -t "$pkgdir/usr/share/fonts/OTF/" static/OTF/*.otf
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" OFL.md
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}
package_ttf-raleway() {
provides=("$pkgbase" "ttf-impallari-raleway-family")
conflicts=("ttf-impallari-raleway-family")
replaces=("ttf-impallari-raleway-family")
cd "$_fname-$pkgver"
install -Dm644 -t "$pkgdir/usr/share/fonts/TTF/" static/TTF/*.ttf
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" OFL.md
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}
package_ttf-raleway-variable() {
provides=("$pkgbase-variable")
cd "$_fname-$pkgver"
install -Dm644 -t "$pkgdir/usr/share/fonts/TTF/" variable/TTF/*.ttf
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" OFL.md
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}
|