blob: 4fcc90d129fab1f205a5d04eadd134c597d90536 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Philipp A. <flying-sheep@web.de>
pkgname=rambox
pkgver=0.5.15
_menupatchver=2
pkgrel=1
pkgdesc='Free and Open Source messaging and emailing app that combines common web applications into one.'
arch=(i686 x86_64)
depends=(electron)
makedepends=(desktop-file-utils asar ruby npm sencha-cmd-6)
url='http://rambox.pro/'
license=(GPL3)
source=("https://github.com/saenzramiro/$pkgname/archive/$pkgver.tar.gz"
"https://github.com/saenzramiro/$pkgname/releases/download/v$pkgver/Rambox-$pkgver-x64.tar.gz"
"context-menu-$_menupatchver.patch::https://github.com/saenzramiro/rambox/pull/1074/commits/c27f5d1771666766e983424b223e2072f839ee41.patch"
"$pkgname.desktop" "$pkgname.js")
sha256sums=('ae35c4b8e0ae24449fdaf480c7000a2fd5b6e6e721f99afcb942f1b898f1268c'
'9b02f4501816a167f80df4d120115226bf45203142fd6cccf6eaa42169a3f7e6'
'25569a4ef5569a49f8873e7e9699b116f72a66ad22719f4e486499e7629332db'
'61ad70a929c402e24c79b8868208310f9b3c4d7801db2b791af38293231ee524'
'3b5ed6f04eea66f239b5ae56ea1ff9e47de156cd38bb54ebc46541daba6091b6')
noextract=("Rambox-$pkgver-x64.tar.gz")
build() {
# retrieve env.js
cd "$srcdir"
tar xOf "Rambox-$pkgver-x64.tar.gz" "Rambox-$pkgver/resources/app.asar" >app.asar
cd "$pkgname-$pkgver"
asar ef ../app.asar env.js
# context menu patch
patch -p1 -i "../context-menu-$_menupatchver.patch"
# install packages
sed -Ei 's/\s+"electron": "[^"]+",//' package.json
npm install
# build
npm run sencha:compile
sed -i "s/require('electron-is-dev')/false/" 'build/production/Rambox/electron/main.js'
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -d "$pkgdir/usr/lib"
cp -r 'build/production/Rambox' "$pkgdir/usr/lib/rambox"
install -Dm755 "$srcdir/$pkgname.js" "$pkgdir/usr/bin/$pkgname"
install -Dm644 'resources/Icon.png' "$pkgdir/usr/share/pixmaps/$pkgname.png"
desktop-file-install "$srcdir/$pkgname.desktop" --dir "$pkgdir/usr/share/applications/"
}
|