PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Maintainer: edio <edio@archlinux.us>

_gitname=randrctl
pkgname=$_gitname-git
pkgdesc="Lightweight profile based screen manager for X"
pkgver=0
pkgrel=1
arch=('any')
url="http://github.com/edio/randrctl"
license=('GPLv3')
makedepends=('git')
depends=('python' 'xorg-xrandr')
optdepends=('bash-completion')
source=('git+https://github.com/edio/randrctl.git')
md5sums=('SKIP')
provides=("$_gitname")
conflicts=("$_gitname")
install="randrctl.install"

pkgver() {
    cd $_gitname
    python setup.py --version | tail -n 1
}

package() {
  cd $_gitname

  # PKGBUILD handles setup
  rm bin/randrctl-setup

  python setup.py install --root="$pkgdir/" --optimize=1
  install -Dm644 randrctl/misc/config.ini "$pkgdir/etc/randrctl/config.ini"
  install -Dm644 randrctl/misc/completion/zsh/_randrctl "$pkgdir/usr/share/zsh/site-functions/_randrctl"
  install -Dm644 randrctl/misc/completion/bash/randrctl "$pkgdir/usr/share/bash-completion/completions/randrctl"
  install -Dm644 randrctl/misc/udev/99-randrctl.rules "$pkgdir/usr/lib/udev/rules.d/99-randrctl.rules"
}

# vim:set ts=2 sw=2 et: