blob: 790360b5402d2ce30b7d7645a6d187f0a2f72dd2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
pkgname=rapidwright
_pkgver=2022.2.0-beta
pkgver="${_pkgver//-/_}"
pkgrel=1
pkgdesc="Build Customized FPGA Implementations for Vivado"
arch=('any')
url='http://www.rapidwright.io/'
license=('custom')
depends=('java-runtime=17' 'jython')
makedepends=('java-environment=17' 'gradle')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/Xilinx/RapidWright/archive/v$_pkgver.tar.gz"
"rapidwright_data-${pkgver}.zip::https://github.com/Xilinx/RapidWright/releases/download/v$_pkgver/rapidwright_data.zip"
"rapidwright_jars-${pkgver}.zip::https://github.com/Xilinx/RapidWright/releases/download/v$_pkgver/rapidwright_jars.zip"
"invoke_rapidwright"
)
sha256sums=('23eb1cf7b65ec8b535ad9dab11923b0120033863bdd2cd12ede9bf2460c94796'
'79320f64c2803b9f2705d774b198611075fe2fec004646e131ef1c34c9c7237b'
'9ac2d7cae455ec2363436593db51389fa477c0f074c7842ad9e6951ea181a7da'
'a0c2f5577cd955cb81aec2839c3c060dc78c6ee48dc99406f67cc902e98f644f')
prepare() {
cd "RapidWright-$_pkgver"
ln -s "$srcdir/jars" .
}
build() {
cd "RapidWright-$_pkgver"
gradle build --exclude-task test
}
package() {
cd "RapidWright-$_pkgver"
install -Dm644 -t "$pkgdir/usr/share/java/$pkgname" "build/libs/rapidwright.jar" jars/*.jar
rm "$pkgdir/usr/share/java/$pkgname/jython-standalone-2.7.2.jar"
mkdir "$pkgdir/usr/share/rapidwright/"
cp -a "$srcdir/data" "$pkgdir/usr/share/rapidwright/"
chmod -R o+rX "$pkgdir/usr/share/rapidwright/"
install -Dm755 -t "$pkgdir/usr/bin" "$srcdir/invoke_rapidwright"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.TXT
}
|