blob: cab969a100783556c348cfd3b6182144eadd1f88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: xiretza <xiretza+aur@xiretza.xyz>
pkgname=rapidwright
_pkgver=2022.1.4-beta
pkgver="${_pkgver//-/_}"
pkgrel=1
pkgdesc="Build Customized FPGA Implementations for Vivado"
arch=('any')
url='http://www.rapidwright.io/'
license=('custom')
depends=('java-runtime=17' 'jython')
makedepends=('java-environment=17' 'gradle')
source=(
"$pkgname-$pkgver.tar.gz::https://github.com/Xilinx/RapidWright/archive/v$_pkgver.tar.gz"
"rapidwright_data-${pkgver}.zip::https://github.com/Xilinx/RapidWright/releases/download/v$_pkgver/rapidwright_data.zip"
"rapidwright_jars-${pkgver}.zip::https://github.com/Xilinx/RapidWright/releases/download/v$_pkgver/rapidwright_jars.zip"
"invoke_rapidwright"
)
sha256sums=('7e869b98070c44b979902f2f4fd008a3bf6f6ec52e69661549316a8e8b5231e5'
'b5652bff9c95fc81a3eec4231924efaa77485962869a880efff2ed6df641a420'
'74233c69a44d864f43fec6304c1d4f787c1d2d47f9acb26a10161c1f05cfe100'
'a0c2f5577cd955cb81aec2839c3c060dc78c6ee48dc99406f67cc902e98f644f')
prepare() {
cd "RapidWright-$_pkgver"
ln -s "$srcdir/jars" .
}
build() {
cd "RapidWright-$_pkgver"
gradle build --exclude-task test
}
package() {
cd "RapidWright-$_pkgver"
install -Dm644 -t "$pkgdir/usr/share/java/$pkgname" "build/libs/rapidwright.jar" jars/*.jar
rm "$pkgdir/usr/share/java/$pkgname/jython-standalone-2.7.2.jar"
mkdir "$pkgdir/usr/share/rapidwright/"
cp -a "$srcdir/data" "$pkgdir/usr/share/rapidwright/"
chmod -R o+rX "$pkgdir/usr/share/rapidwright/"
install -Dm755 -t "$pkgdir/usr/bin" "$srcdir/invoke_rapidwright"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.TXT
}
|