blob: 98ed509fa7f297b0e334a53e62cf5617b4be4d43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: Ashley Bone <ashley DOT bone AT pm DOT me>
# Orginally Packaged By: Mantas Mikulėnas <grawity@gmail.com>
pkgname=rasdaemon
pkgver=0.6.5
pkgrel=4
pkgdesc="Logging daemon for Platform Reliability, Availability and Serviceability (RAS), replacing mcelog"
arch=(i686 x86_64)
url="https://pagure.io/rasdaemon"
license=(GPL2)
depends=(
# For rasdaemon:
sqlite
# For ras-mc-ctl:
dmidecode
perl
perl-dbd-sqlite
)
source=("https://www.infradead.org/~mchehab/rasdaemon/rasdaemon-$pkgver.tar.bz2")
sha256sums=('5a4745fd4161f2920a9e9f5eecc4f53c797e27b8a2c3c217070bb6ceaa7c1c44')
# Git tree: http://git.infradead.org/users/mchehab/rasdaemon.git
prepare() {
cd "$srcdir/$pkgname-$pkgver"
autoreconf -vfi
}
build() {
cd "$srcdir/$pkgname-$pkgver"
CFLAGS="$CFLAGS -fcommon" ./configure \
--prefix=/usr \
--sbindir=/usr/bin \
--sysconfdir=/etc \
--localstatedir=/var \
--enable-aer \
--enable-arm \
--enable-extlog \
--enable-hisi-ns-decode \
--enable-mce \
--enable-non-standard \
--enable-devlink \
--enable-diskerror \
--enable-sqlite3 \
;
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
make DESTDIR="$pkgdir" install
for unit in {rasdaemon,ras-mc-ctl}.service; do
install -D -m 644 misc/$unit "$pkgdir"/usr/lib/systemd/system/$unit
done
rm -rf "$pkgdir"/usr/include
}
# vim: ts=2:sw=2:et:ft=sh
|