blob: f2f19700a8d91dcd359f5e12234d3c2c8ac11728 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
# Contributor: VirtualTam <virtualtam -at- flibidi -dot- net>
_pkgname="raul"
pkgname="${_pkgname}-git"
pkgver=1.0.0.r603.10fb82f
pkgrel=2
epoch=1
pkgdesc="Realtime Audio Utility Library for audio and musical applications (git version)"
arch=('i686' 'x86_64')
url="http://drobilla.net/software/raul/"
license=('GPL3')
depends=()
makedepends=('doxygen' 'git' 'python')
provides=("$_pkgname" "$_pkgname=${pkgver//.r*/}")
conflicts=("$_pkgname")
source=("${_pkgname}::git+https://gitlab.com/drobilla/${_pkgname}.git"
'autowaf::git+https://gitlab.com/drobilla/autowaf.git')
sha256sums=('SKIP' 'SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
local ver=`grep "^RAUL_VERSION" wscript | cut -d "'" -f 2`
echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}"
git submodule init
git config submodule.waflib.url "${srcdir}/autowaf"
git submodule update
}
build(){
cd "${srcdir}/${_pkgname}"
python waf configure \
--prefix="/usr" \
--docs \
--docdir="/usr/share/doc/${pkgname}"
python waf build ${MAKEFLAGS}
}
package() {
cd "${srcdir}/${_pkgname}"
python waf install --destdir="${pkgdir}"
install -m 644 README NEWS "${pkgdir}/usr/share/doc/$pkgname"
mv "${pkgdir}/usr/share/doc/$pkgname/raul-1/html" "${pkgdir}/usr/share/doc/$pkgname"
rm -rf "${pkgdir}/usr/share/doc/$pkgname/raul-1"
}
|