blob: 02d2eff1ad83b9292c92f8522e18b82fc32d8f00 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=rav1e-git
pkgver=0.6.3.r22.g3ffd4079
pkgrel=1
pkgdesc="The fastest and safest AV1 encoder"
arch=('i686' 'x86_64')
url="https://github.com/xiph/rav1e"
license=('BSD' 'custom')
depends=('gcc-libs')
makedepends=('git' 'rust' 'nasm' 'cargo-c')
provides=("rav1e=$pkgver" 'librav1e.so')
conflicts=('rav1e')
options=('staticlibs')
source=("git+https://github.com/xiph/rav1e.git")
sha256sums=('SKIP')
prepare() {
cd "rav1e"
if [ ! -f "Cargo.lock" ]; then
cargo update
fi
cargo fetch
}
pkgver() {
cd "rav1e"
_tag=$(git tag -l --sort -v:refname | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//;s/-/./g'
}
check() {
cd "rav1e"
#cargo test \
# --frozen \
# --release
}
package() {
cd "rav1e"
cargo install \
--no-track \
--frozen \
--root "$pkgdir/usr" \
--path "$srcdir/rav1e"
# for librav1e
cargo cinstall \
--frozen \
--destdir "$pkgdir" \
--prefix "/usr"
install -Dm644 "README.md" -t "$pkgdir/usr/share/doc/rav1e"
install -Dm644 {LICENSE,PATENTS} -t "$pkgdir/usr/share/licenses/rav1e"
}
|