PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Maintainer: Björn "zemrod" Bravin <sinon dot adastrum at gmail dot com>
_bpn=rawk
pkgname=$_bpn-git
pkgver=0.6.8.73.gb14fe60
pkgrel=2
pkgdesc="a minimal tool inspired by gawks string seperation ability"
arch=('x86_64')
url="https://github.com/Zemrod/$_bpn"
license=('MIT')
depends=('gcc-libs')
makedepends=('rust' 'git')
provides=('rawk')
conflicts=('rawk')
source=("git+$url")
md5sums=('SKIP')

pkgver() {
	cd "$_bpn"
	printf "$(grep '^version =' Cargo.toml|head -n1|cut -d\" -f2).$(git rev-list --count HEAD).g$(git rev-parse --short HEAD)"
}

build() {
	cd "$srcdir/$_bpn"
	cargo build --release --locked --all-features --target-dir=target
}

check() {
	cd "$srcdir/$_bpn"
	cargo test --release --locked --target-dir=target
}

package() {
	cd "$srcdir/$_bpn"
	install -Dm755 "target/release/rawk" "$pkgdir/usr/bin/$_bpn"
	install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}