blob: c53b66f2f2bd2ece3a94913d432d562292abdf26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: OSAMC <https://github.com/osam-cologne/archlinux-proaudio>
# Contributor: Christopher Arndt <aur -at- chrisarndt -dot- de>
_name=RaySession
pkgname=${_name,,}
pkgver=0.14.3
pkgrel=2
pkgdesc="Session manager for audio programs using the Non Session Manager (NSM) API"
arch=(any)
url='https://github.com/Houston4444/RaySession'
license=(GPL)
depends=(hicolor-icon-theme dbus-python python-pyalsa python-pyqt5 python-pyliblo python-pyxdg qt5-svg)
makedepends=(qt5-tools)
optdepends=(
'python-gobject: additional JACK helper scripts'
'python-pyjacklib: additional JACK helper scripts'
)
groups=(pro-audio)
source=("https://github.com/Houston4444/RaySession/releases/download/v$pkgver/$_name-$pkgver-source.tar.gz"
'raysession-makefile-destdir.patch')
sha256sums=('dfe835cdd8c6931344a72b8abb1ce1af6a7d8241058d802ca387cf79d6e39a56'
'943c821d4d5cae581004ca54030b720ac835a03cd7691492bcbcb6e146bb078a')
prepare() {
cd $_name-$pkgver
patch -p1 -N -r - -i "$srcdir"/raysession-makefile-destdir.patch
}
build() {
cd $_name-$pkgver
make
}
package() {
cd $_name-$pkgver
make -j 1 PREFIX=/usr DESTDIR="$pkgdir" install
# remove broken symlink
rm -f "$pkgdir"/usr/share/raysession/src/bin/ray-jackpatch-mon
# client templates installed @ /etc/xdg/raysession & /usr/share/raysession
# we need only one
rm -rf "$pkgdir"/usr/share/raysession/client_templates
install -Dm644 CHANGELOG README.md TODO TRANSLATORS plans.md \
-t "$pkgdir"/usr/share/doc/$pkgname
}
|