PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Martin Drawitsch <martin dot drawitsch at gmail dot com>

pkgname=rbdl-git
_name=rbdl-orb
pkgrel=1
pkgver=3.0.0+5.g4e36ba8
pkgdesc="RBDL - Rigid Body Dynamics Library. Git version."
url="https://github.com/ORB-HD/rbdl-orb"
arch=('x86_64')
license=('zlib')
makedepends=('cmake' 'eigen3' 'git'
             'lua51'
             'python' 'cython' 'python-numpy')
optdepends=('lua51: Lua model add-on'
            'python: Python wrapper'
            'cython: Python wrapper'
            'python-numpy: Python wrapper'
            'python-scipy: Python wrapper')
provides=('rbdl')
conflicts=('rbdl' 'rbdl-hg')
source=("git+https://github.com/ORB-HD/rbdl-orb.git")
sha1sums=('SKIP')

pkgver() {
    cd ${_name}
    git describe --always --dirty --tags | sed "s/^v//;s/-/+/;s/-/./g"
}

build() {
    mkdir -p build
    cd build
    cmake ../${_name} -DCMAKE_INSTALL_PREFIX=/usr \
                      -DRBDL_BUILD_ADDON_LUAMODEL=ON \
                      -DLUA_LIBRARIES=lua5.1 \
                      -DLUA_INCLUDE_DIR=/usr/include/lua5.1 \
                      -DRBDL_BUILD_PYTHON_WRAPPER=ON
    make
}

package() {
    cd build
    make DESTDIR=${pkgdir} install
    cd python
    python setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1 --skip-build
}