blob: a15a8aeb9330aa33f77b73906c020c8b3b060f1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
# Maintainer: gardenapple@posteo.net
pkgname=readability-cli
pkgver=2.2.5
pkgrel=1
pkgdesc="Firefox Reader Mode in your terminal! - CLI tool for Mozilla's Readability library"
arch=('any')
url="https://www.npmjs.com/package/$pkgname"
license=('GPL3')
depends=('nodejs')
makedepends=('npm' 'jq')
optdepends=('bash-completion: Bash completion'
'zsh: zsh completion')
source=("https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz")
noextract=("$pkgname-$pkgver.tgz")
sha256sums=('6bf4ca08e2b37ba5f014f4105927e116f11474f62c48a666b18562729008be23')
b2sums=('7668f5fc19427e3e16c29af1b4f8d8d64e58aa524873ce1a9470cb1f260b87281906fbc470ea3a75c3b1f6460edd49ecada1c953a387e49372f1f50a1f0e59e0')
package() {
npm install -g --prefix "$pkgdir/usr" "$srcdir/$pkgname-$pkgver.tgz"
# Shell completions
cd "$pkgdir/usr/bin"
SHELL=/bin/zsh ./readable --completion \
| install -Dm644 /dev/stdin "$pkgdir/usr/share/zsh/site-functions/_readable"
SHELL=/bin/bash ./readable --completion \
| install -Dm644 /dev/stdin "$pkgdir/usr/share/bash-completion/completions/readable"
cd -
# Non-deterministic race in npm gives 777 permissions to random directories.
# See https://github.com/npm/cli/issues/1103 for details.
find "$pkgdir/usr" -type d -exec chmod 755 {} +
# Remove references to $pkgdir
find "$pkgdir" -type f -name package.json -print0 | xargs -0 sed -i "/_where/d"
# Remove references to $srcdir
local tmppackage="$(mktemp)"
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 644 "$pkgjson"
find "$pkgdir" -type f -name package.json | while read pkgjson; do
local tmppackage="$(mktemp)"
jq 'del(.man)' "$pkgjson" > "$tmppackage"
mv "$tmppackage" "$pkgjson"
chmod 644 "$pkgjson"
done
}
|