blob: 5d10cb1a3bf5e271a2708b9eb78be909adfee085 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
|
# Maintainer: Donald Webster <fryfrog@gmail.com>
# Helpful url: https://readarr.servarr.com/v1/update/readarr/updatefile?os=linux&runtime=netcore&arch=x64
pkgname="readarr-develop"
pkgver=0.3.14.2358
pkgrel=1
pkgdesc="Audio and eBook download automation for usenet and torrents."
arch=('x86_64' 'aarch64' 'armv7h')
url="https://github.com/Readarr/Readarr"
license=("GPL3")
depends=(
'sqlite'
'chromaprint'
)
options=(
'!strip'
'staticlibs'
)
provides=('readarr')
conflicts=('readarr')
optdepends=('calibre: calibre-server as root folder'
'sabnzbd: usenet downloader'
'nzbget: usenet downloader'
'transmission-cli: torrent downloader (CLI and daemon)'
'transmission-gtk: torrent downloader (GTK+)'
'transmission-qt: torrent downloader (Qt)'
'deluge: torrent downloader'
'rtorrent: torrent downloader'
'qbittorrent: torrent downloader'
'qbittorrent-nox: torrent downloader (no X)'
'jackett: torrent indexer proxy')
source_x86_64=("readarr.${pkgver}.linux-core-x64.tar.gz::https://readarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=x64")
source_aarch64=("readarr.${pkgver}.linux-core-arm64.tar.gz::https://readarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm64")
source_armv7h=("readarr.${pkgver}.linux-core-arm.tar.gz::https://readarr.servarr.com/v1/update/develop/updatefile?version=${pkgver}&os=linux&runtime=netcore&arch=arm")
source=('readarr.service'
'readarr.tmpfiles'
'readarr.sysusers'
'package_info')
sha512sums=('225a3a7e3fec01d6b223998195ffae93abf0c7cfaeed5d6f54468ec891d37239ffe51d0d5581a1ac96922ab331b0af58a29397bbbf00f2c083e2caf6fa5667d4'
'b34389cf2966a7a1a1fe6708303641e144191a95001c5ca6e570e9d50ba334fcbc1603852c3c2bfe008d97aaf54207690c689f00dd63378157af33ceebbbb089'
'99f8210754ea5ec742ba6b0b9f05c8312237cb0225bc0d28a2a8ee8362b464da0880499b64ea58c84b64c0eb727748c3c15630cedb8785d7d94d856c76cf17eb'
'e7d23886761a5052d9c9efa24d938bce7ab52b19713a50cc5338f1273bba6615c49ccf1612c412320fd7ff91fff4bff4e95a58db83ae7bd6b6bc83568ffeb90f')
sha512sums_x86_64=('7172e629901e2a68d6314e34e4719c06aa616f6bd81c45bf044d33bd1d8d7ffaac90607daeb3f5534ff5745d01cc9ab2ba34d9ea2aecdb44d6e27656d229b9cc')
sha512sums_aarch64=('46e4f53cd33b2f8c43efd438b846956a7f5bc406bdb118338d57b90f1f5eabe1bce17e04e62a035df7e4a7936ff5c6555ce98009ac1539eb57fa9c4c14d7868b')
sha512sums_armv7h=('aefecc28ff713cc09457fd35441482f3703b1167da32f10bc43e8a5fa60d405b1a2bc638c61fdc4abc905f5d6ee441601e0a7d64b40be2b02f07b3d40aca474c')
package() {
# Update environment isn't needed.
rm -rf "${srcdir}/Readarr/Readarr.Update"
# Remove unneeded fpcalc
rm -f "${srcdir}/Readarr/fpcalc"
install -d -m 755 "${pkgdir}/usr/lib/readarr/bin"
cp -dpr --no-preserve=ownership "${srcdir}/Readarr/"* "${pkgdir}/usr/lib/readarr/bin"
chmod -R a=,a+rX,u+w "${pkgdir}/usr/lib/readarr/bin"
chmod +x "${pkgdir}/usr/lib/readarr/bin/Readarr"
# Disable built in updater.
install -D -m 644 "${srcdir}/package_info" "${pkgdir}/usr/lib/readarr"
echo "PackageVersion=${pkgver}-${pkgrel}" >> "${pkgdir}/usr/lib/readarr/package_info"
install -D -m 644 "${srcdir}/readarr.service" "${pkgdir}/usr/lib/systemd/system/readarr.service"
install -D -m 644 "${srcdir}/readarr.sysusers" "${pkgdir}/usr/lib/sysusers.d/readarr.conf"
install -D -m 644 "${srcdir}/readarr.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/readarr.conf"
}
|